afl Amibroker Alligator

_SECTION_BEGIN( "Filter Sinyal" );
FilterSinyal = ParamList( "FIlter Sinyal", "Sinyal LONG|Sinyal SHORT|SEMUA Sinyal", 0 );
_SECTION_END();

_SECTION_BEGIN( "Price" );
SetChartOptions( 0, chartShowArrows | chartShowDates );
_N( Title = StrFormat( "{{NAME}} - {{INTERVAL}} {{DATE}} Open %g, Hi %g, Lo %g, Close %g (%.1f%%) {{VALUES}}", O, H, L, C, SelectedValue( ROC( C, 1 ) ) ) );
Plot( C, "Close", ParamColor( "Color", colorDefault ), styleNoTitle | ParamStyle( "Style" ) | GetPriceStyle() );
_SECTION_END();

_SECTION_BEGIN( "Tick" );
TickSell=
IIf( DateNum() < 1140106,
    IIf( Close < 200, 1,
    IIf( Close >= 200 AND Close < 500, 5,
    IIf( Close >= 500 AND Close < 2000, 10,
    IIf( Close >= 2000 AND Close < 5000, 25,
    IIf( Close >= 5000, 50, 0 ) ) ) ) ),

IIf( DateNum() >= 1140106 AND DateNum() < 1160502,
    IIf( Close < 500, 1,
    IIf( Close >= 500 AND Close < 5000, 5,
    IIf( Close >= 5000, 25, 0 ) ) ),

IIf( DateNum() >= 1160502,
    IIf( Close < 200, 1,
    IIf( Close >= 200 AND Close < 500, 2,
    IIf( Close >= 500 AND Close < 2000, 5,
    IIf( Close >= 2000 AND Close < 5000, 10,
    IIf( Close >= 5000, 25, 0 ) ) ) ) ), 0 ) ) );

TickBuy=
IIf( DateNum() < 1140106,
    IIf( Close < 200, 1,
    IIf( Close >= 200 AND Close < 500, 5,
    IIf( Close >= 500 AND Close < 2000, 10,
    IIf( Close >= 2000 AND Close < 5000, 25,
    IIf( Close >= 5000, 50, 0 ) ) ) ) ),

IIf( DateNum() >= 1140106 AND DateNum() < 1160502,
    IIf( Close < 500, 1,
    IIf( Close >= 500 AND Close < 5000, 5,
    IIf( Close >= 5000, 25, 0 ) ) ),

IIf( DateNum() >= 1160502,
    IIf( Close < 200, 1,
    IIf( Close >= 200 AND Close < 500, 2,
    IIf( Close >= 500 AND Close < 2000, 5,
    IIf( Close >= 2000 AND Close < 5000, 10,
    IIf( Close >= 5000, 25, 0 ) ) ) ) ), 0 ) ) );
_SECTION_END();


_SECTION_BEGIN( "Alligator" );
Lips_Period    = Param( "Periode Lips", 5, 3, 8, 1 );
Teeth_Period    = Param( "Periode Teeth", 8, 5, 13, 1 );
Jaw_Period        = Param( "Periode Jaw", 13, 8, 21, 1 );

Lips_Shift        = Param( "Shift Lips", 3, 3, 8, 1 );
Teeth_Shift    = Param( "Shift Teeth", 5, 5, 13, 1 );
Jaw_Shift        = Param( "Shift Jaw", 8, 8, 21, 1 );

Method         = ParamList( "Mid Price", "( H + L ) / 2|( O + H + L + C ) / 4|Open|High|Low|Close", 0 );

if ( Method == "( H + L ) / 2" )
{
    MidPrice = ( H + L ) / 2;
}

if ( Method == "( O + H + L + C ) / 4" )
{
    MidPrice = ( O + H + L + C ) / 4;
}

if ( Method == "Open" )
{
    MidPrice = O;
}

if ( Method == "High" )
{
    MidPrice = H;
}

if ( Method == "Low" )
{
    MidPrice = L;
}

if ( Method == "Close" )
{
    MidPrice = C;
}

Lips     = MA( MidPrice, Lips_Period );
Teeth     = MA( MidPrice, Teeth_Period );
Jaw     = MA( MidPrice, Jaw_Period );

for ( i = Lips_Period + 1; i < BarCount; i++ )
{
    iSum = ( Lips[i-1] * ( Lips_Period - 1 ) ) + MidPrice[i];
    Lips[i] = iSum / Lips_Period;
}

for ( j = Teeth_Period + 1; j < BarCount; j++ )
{
    jSum = ( Teeth[j-1] * ( Teeth_Period - 1 ) ) + MidPrice[j];
    Teeth[j] = jSum / Teeth_Period;
}

for ( k = Jaw_Period + 1; k < BarCount; k++ )
{
    kSum = ( Jaw[k-1] * ( Jaw_Period - 1 ) ) + MidPrice[k];
    Jaw[k] = kSum / Jaw_Period;
}

GatorAbove0 = abs( Jaw - Teeth );
GatorBelow0 = -( abs( Teeth - Lips ) );

PlotOHLC( Lips, Lips, Lips, Lips, "Lips", ParamColor( "Color Lips", colorGreen ), styleCloud | styleNoLabel, Null, Null, Lips_Shift, -2 );
PlotOHLC( Teeth, Teeth, Teeth, Teeth, "Teeth", ParamColor( "Color Teeth", colorRed ), styleCloud | styleNoLabel, Null, Null, Teeth_Shift, -2 );
PlotOHLC( Jaw, Jaw, Jaw, Jaw, "Jaw", ParamColor( "Color Jaw", colorBlue ), styleCloud | styleNoLabel, Null, Null, Jaw_Shift, -2 );
_SECTION_END();

_SECTION_BEGIN( "AO AND AC" );
AOFast    = MA( MidPrice, Param( "Periode AO Fast", 5, 3, 100, 1 ) );
AOSlow    = MA( MidPrice, Param( "Periode AO Slow", 34, 15, 300, 1 ) );
AO         = AOFast - AOSlow;
AC        = AO - MA( AO, Param( "Periode Signal line (AC)", 5, 3, 100, 1 ) );
AOUB    = AO > Ref( AO, -1 );
AODB    = AO < Ref( AO, -1 );
ACUB    = AC > Ref( AC, -1 );
ACDB    = AC < Ref( AC, -1 );
GrnBar    = AOUB AND ACUB;
RedBar    = AODB AND ACDB;
_SECTION_END();

_SECTION_BEGIN( "Fractals" );
fUpA =
    ( Ref( H, -2 )  > Ref( H, -4 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -3 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -1 ) ) AND
    ( Ref( H, -2 )  > H );

fUpB =
    ( Ref( H, -2 )  > Ref( H, -5 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -4 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -3 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -1 ) ) AND
    ( Ref( H, -2 )  > H );

fUpC =
    ( Ref( H, -2 )  > Ref( H, -6 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -5 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -4 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -3 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -1 ) ) AND
    ( Ref( H, -2 )  > H );

fUpD =
    ( Ref( H, -2 )  > Ref( H, -6 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -5 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -4 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -3 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -1 ) ) AND
    ( Ref( H, -2 )  > H );

fUpE =
    ( Ref( H, -2 )  > Ref( H, -8 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -7 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -6 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -5 ) ) AND
    ( Ref( H, -2 ) == Ref( H, -4 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -3 ) ) AND
    ( Ref( H, -2 )  > Ref( H, -1 ) ) AND
    ( Ref( H, -2 )  > H );

//Setting Fractal Down
fDnA =
    ( Ref( L, -2 )  < Ref( L, -4 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -3 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -1 ) ) AND
    ( Ref( L, -2 )  < L );

fDnB =
    ( Ref( L, -2 )  < Ref( L, -5 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -4 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -3 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -1 ) ) AND
    ( Ref( L, -2 )  < L );

fDnC =
    ( Ref( L, -2 )  < Ref( L, -6 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -5 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -4 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -3 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -1 ) ) AND
    ( Ref( L, -2 )  < L );

fDnD =
    ( Ref( L, -2 )  < Ref( L, -6 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -5 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -4 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -3 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -1 ) ) AND
    ( Ref( L, -2 )  < L );

fDnE =
    ( Ref( L, -2 )  < Ref( L, -8 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -7 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -6 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -5 ) ) AND
    ( Ref( L, -2 ) == Ref( L, -4 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -3 ) ) AND
    ( Ref( L, -2 )  < Ref( L, -1 ) ) AND
    ( Ref( L, -2 )  < L );

var1    = ValueWhen( fUpE OR fUpD OR fUpC OR fUpB OR fUpA, Ref( H, -2 ), 1 );
var2    = ValueWhen( fDnE OR fDnD OR fDnC OR fDnB OR fDnA, Ref( L, -2 ), 1 );
FracUp    = HighestSince( var1 > 0, var1, 1 );
FracDn    = LowestSince ( var2 > 0, var2, 1 );

Plot( FracUp, "F+", ParamColor( "Color F+", colorViolet ), ParamStyle( "Style F+", styleLine | styleDashed ) );
Plot( FracDn, "F-", ParamColor( "Color F-", colorGrey40 ), ParamStyle( "Style F-", styleLine | styleDashed ) );
_SECTION_END();

_SECTION_BEGIN( "Volume" );
Satuan = ParamToggle( "Satuan Volume", "Lot (100 lembar)|Lembar", 0 );

if ( Satuan == 0 )
{
    Vol = V;
}

if ( Satuan == 1 )
{
    Vol = V / 100;
}

_SECTION_END();

_SECTION_BEGIN( "WiseMan" );
WM1L     = L < Ref( L, -1 ) AND C > ( ( H + L ) / 2 ) AND AODB AND AO < 0 AND ( O < Ref( Teeth, -5 ) AND C < Ref( Teeth, -5 ) ) AND ( L < Ref( Teeth, -5 ) AND H < Ref( Teeth, -5 ) );
WM1S    = H > Ref( H, -1 ) AND C < ( ( H + L ) / 2 ) AND AOUB AND AO > 0 AND ( O > Ref( Teeth, -5 ) AND C > Ref( Teeth, -5 ) ) AND ( L > Ref( Teeth, -5 ) AND H > Ref( Teeth, -5 ) );
WM2L    = Ref( AODB, -3 ) AND Ref( AOUB, -2 ) AND Ref( AOUB, -1 ) AND AOUB;
WM2S    = Ref( AOUB, -3 ) AND Ref( AODB, -2 ) AND Ref( AODB, -1 ) AND AODB;
WM3L    = Cross( C, FracUp );
WM3S    = Cross( FracDn, C );
VolAverage        = MA( Vol, Periode = Param( "Periode Vol. Avg", 20, 10, 100, 1 ) );
AveragePrice    = ( O + H + L + C ) / 4;
AverageValue    = IIf( Satuan == 0, AveragePrice * V * 100, AveragePrice * V );
FilterValue    = ParamStr( "Filter Value", "10000000000" );

Buy1            = WM1L;
Buy2            = WM2L AND NOT WM3L;
Buy3            = WM3L;
Buy4            = WM2L AND WM3L;
Buy                = ( Buy1 OR Buy2 OR Buy3 OR Buy4 ) AND AverageValue >= StrToNum( FilterValue );

Sell1            = WM1S;
Sell2            = WM2S AND NOT WM3S;
Sell3            = WM3S;
Sell4            = WM2S AND WM3S;
Sell            = Sell1 OR Sell2 OR Sell3 OR Sell4;

Sinyal            = WriteIf( WM1L, "WiseMan 1 Long", WriteIf( ( WM2L AND NOT WM3L ), "WiseMan 2 Long", WriteIf( WM3L, "WiseMan 3 Long", WriteIf( ( WM2L AND WM3L ), "WiseMan 2 dan 3 Long",
                  WriteIf( WM1S, "WiseMan 1 Short", WriteIf( ( WM2S AND NOT WM3S ), "WiseMan 2 Short", WriteIf( WM3S, "WiseMan 3 Short", WriteIf( ( WM2S AND WM3S ), "WiseMan 2 dan 3 Short", "" ) ) ) ) ) ) ) );
/*
WM1LCom = "Sinyal WiseMan 1 Long, perlu konfirmasi sudut angulasi, BUY stop Rp. " + WriteVal( ValueWhen( WM1L, H + TickBuy ), 1.0 ) + ". Stoploss Rp. " + WriteVal( ValueWhen( WM1L, L - TickSell ), 1.0 ) + "." ;
WM1SCom = "Sinyal WiseMan 1 Short, perlu konfirmasi sudut angulasi, SELL stop Rp. " + WriteVal( ValueWhen( WM1S, L - TickSell ), 1.0 ) + ". Stoploss Rp. " + WriteVal( ValueWhen( WM1S, H + TickBuy ), 1.0 ) + "." ;
WM2LCom = "Sinyal WiseMan 2 Long (Add-On), perlu konfirmasi valid close di atas Rp. " + WriteVal( ValueWhen( WM2L, H ), 1.0 ) + ". Jika terbentuk di bawah teeth, harus didahului dengan sinyal WiseMan 1 Long yang valid." ;
WM2SCom = "Sinyal WiseMan 2 Short (Add-On), perlu konfirmasi valid close di bawah Rp. " + WriteVal( ValueWhen( WM2S, L ), 1.0 ) + ". Jika terbentuk di atas teeth, harus didahului dengan sinyal WiseMan 1 Short yang valid.";
WM3LCom = "Sinyal WiseMan 3 Long, perhatikan trend alligator. Best buy di sekitar Rp. " + WriteVal( ValueWhen( WM3L, fracup ), 1.0 ) + " - Rp. " + WriteVal( ValueWhen( WM3L, C ), 1.0 ) + ". Jika terbentuk di bawah teeth harus didahului sinyal WiseMan 1 dan WiseMan 2 Long yang valid.";
WM3SCom = "Sinyal WiseMan 3 Short, perhatikan trend alligator. Best sell di sekitar Rp. " + WriteVal( ValueWhen( WM3S, C ), 1.0 ) + " - Rp. " + WriteVal ( ValueWhen( WM3S, fracdn ), 1.0 ) + ". Jika terbentuk di atas teeth harus digahului sinyal WiseMan 1 dan WiseMan 2 Short yang valid.";
WM4LCom = "Sinyal WiseMan 2 dan WiseMan 3 Long, perhatikan trend alligator. Best buy di sekitar Rp. " + WriteVal( ValueWhen( WM3L, fracup ), 1.0 ) + " - Rp. " + WriteVal( ValueWhen( WM3L, C ), 1.0 ) + ". Jika terbentuk di bawah teeth harus didahului sinyal WiseMan 1 Long yang valid.";
WM4SCom = "Sinyal WiseMan 2 dan WiseMan 3 Short, perhatikan trend alligator. Best sell di sekitar Rp. " + WriteVal( ValueWhen( WM3S, C ), 1.0 ) + " - Rp. " + WriteVal ( ValueWhen( WM3S, fracdn ), 1.0 ) + ". Jika terbentuk di atas teeth harus digahului sinyal WiseMan 1 Short yang valid.";
*/
Comment        = WriteIf( WM1L, "Sinyal WiseMan 1 Long, perlu konfirmasi sudut angulasi, BUY stop Rp. " + WriteVal( ValueWhen( WM1L, H + TickBuy ), 1.0 ) + ". Stoploss Rp. " + WriteVal( ValueWhen( WM1L, L - TickSell ), 1.0 ) + ".",
              WriteIf( ( WM2L AND NOT WM3L ), "Sinyal WiseMan 2 Long (Add-On), perlu konfirmasi valid close di atas Rp. " + WriteVal( ValueWhen( WM2L, H ), 1.0 ) + ". Jika terbentuk di bawah teeth, harus didahului dengan sinyal WiseMan 1 Long yang valid.",
              WriteIf( WM3L, "Sinyal WiseMan 3 Long, perhatikan trend alligator. Best buy di sekitar Rp. " + WriteVal( ValueWhen( WM3L, fracup ), 1.0 ) + " - Rp. " + WriteVal( ValueWhen( WM3L, C ), 1.0 ) + ". Jika terbentuk di bawah teeth harus didahului sinyal WiseMan 1 dan WiseMan 2 Long yang valid.",
              WriteIf( ( WM2L AND WM3L ), "Sinyal WiseMan 2 dan WiseMan 3 Long, perhatikan trend alligator. Best buy di sekitar Rp. " + WriteVal( ValueWhen( WM3L, fracup ), 1.0 ) + " - Rp. " + WriteVal( ValueWhen( WM3L, C ), 1.0 ) + ". Jika terbentuk di bawah teeth harus didahului sinyal WiseMan 1 Long yang valid.",
              WriteIf( WM1S, "Sinyal WiseMan 1 Short, perlu konfirmasi sudut angulasi, SELL stop Rp. " + WriteVal( ValueWhen( WM1S, L - TickSell ), 1.0 ) + ". Stoploss Rp. " + WriteVal( ValueWhen( WM1S, H + TickBuy ), 1.0 ) + ".",
              WriteIf( ( WM2S AND NOT WM3S ), "Sinyal WiseMan 2 Short (Add-On), perlu konfirmasi valid close di bawah Rp. " + WriteVal( ValueWhen( WM2S, L ), 1.0 ) + ". Jika terbentuk di atas teeth, harus didahului dengan sinyal WiseMan 1 Short yang valid.",
              WriteIf( WM3S, "Sinyal WiseMan 3 Short, perhatikan trend alligator. Best sell di sekitar Rp. " + WriteVal( ValueWhen( WM3S, C ), 1.0 ) + " - Rp. " + WriteVal ( ValueWhen( WM3S, fracdn ), 1.0 ) + ". Jika terbentuk di atas teeth harus digahului sinyal WiseMan 1 dan WiseMan 2 Short yang valid.",
              WriteIf( ( WM2S AND WM3S ), "Sinyal WiseMan 2 dan WiseMan 3 Short, perhatikan trend alligator. Best sell di sekitar Rp. " + WriteVal( ValueWhen( WM3S, C ), 1.0 ) + " - Rp. " + WriteVal ( ValueWhen( WM3S, fracdn ), 1.0 ) + ". Jika terbentuk di atas teeth harus digahului sinyal WiseMan 1 Short yang valid.", "" ) ) ) ) ) ) ) );

ShowShapes = ParamToggle( "Show Shapes", "Yes|No", 0 );
if ( ShowShapes == 0 )
{
   // PlotShapes( IIf( Buy4, shapeDigit4, IIf( Buy1, shapeDigit1, IIf( Buy2, shapeDigit2, IIf( Buy3, shapeDigit3, 0 ) ) ) ), colorGreen, 0, L, -10 );
   PlotShapes( IIf( Buy4, shapeDigit4, IIf( Buy2, shapeDigit2, IIf( Buy3, shapeDigit3, 0 ) ) ), colorGreen, 0, L, -10 );
   // PlotShapes( IIf( Sell4, shapeDigit4, IIf( Sell1, shapeDigit1, IIf( Sell2, shapeDigit2, IIf( Sell3, shapeDigit3, 0 ) ) ) ), colorOrange, 0, H, 10 );
   PlotShapes( IIf( Sell4, shapeDigit4, IIf( Sell2, shapeDigit2, IIf( Sell3, shapeDigit3, 0 ) ) ), colorOrange, 0, H, 10 );
}

_SECTION_END();



_SECTION_BEGIN( "Filter" );
ExitLong        = round( Ref( Teeth, -5 ) / TickSell ) * TickSell;
ExitShort        = round( Ref( Teeth, -5 ) / TickBuy ) * TickBuy;
Risk            = IIf( ExitLong < FracDn, ( Close - FracDn ) / Close * 100, ( Close - ExitLong ) / Close * 100 );

BuyPrice        = IIf( Buy1, ValueWhen( Buy1, H + TickBuy ), IIf( Buy2, ValueWhen( Buy2, H + TickBuy ), IIf( Buy3, ValueWhen( Buy3, C ), IIf ( Buy4, ValueWhen( Buy4, C ), Null ) ) ) );;
SellPrice        = IIf( Sell1, ValueWhen( Sell1, L + TickSell ), IIf( Sell2, ValueWhen( Sell2, L + TickSell ), IIf( Sell3, ValueWhen( Sell3, C ), IIf ( Sell4, ValueWhen( Sell4, C ), Null ) ) ) );;

if ( FilterSinyal == "Sinyal LONG" )
{
    Filter        = Buy AND AverageValue >= StrToNum( FilterValue );
}
else
if ( FilterSinyal == "Sinyal SHORT" )
{
    Filter        = Sell;
}
else
if ( FilterSinyal == "SEMUA Sinyal" )
{
    Filter        = ( Buy AND AverageValue >= StrToNum( FilterValue ) ) OR Sell;
}

AddTextColumn( FullName(), "Full Name", 1.0, colorDefault, colorDefault, 220 );
AddTextColumn( Sinyal, "Sinyal", 1.0, colorDefault, colorDefault, 100 );
AddColumn( Close, "Close", 1.0, colorDefault, colorDefault, 55 );
AddColumn( Vol, "Volume (lot)", 1.0, colorDefault, IIf( Vol > VolAverage, colorLime, colorDefault ) );
AddColumn( VolAverage, "Vol.Avg (lot)", 1.0 );
AddColumn( ExitLong, "Exit Point", 1.0, colorDefault, colorDefault, 60 );
AddColumn( Risk, "Risk (%)", 1.2, colorDefault, colorDefault, 60 );
AddTextColumn( Comment, "Comment", 1.0, colorDefault, colorDefault, 1000 );

SetSortColumns(1);
_SECTION_END();

//----------------- MFI Definition -------------------------------
_SECTION_BEGIN("MFI");
D0 = (High-Low)/Volume>= Ref((High-Low)/Volume,-1) AND Volume >= Ref( Volume, -1 );// Green
D1 = (High-Low)/Volume< Ref((High-Low)/Volume,-1) AND Volume <Ref( Volume, -1 );// Red
D2 = (High-Low)/Volume>= Ref((High-Low)/Volume,-1) AND Volume < Ref( Volume, -1 );// Blue
D3 = (High-Low)/Volume< Ref((High-Low)/Volume,-1) AND Volume >= Ref( Volume, -1 );// Pink

dynamic_color = IIf( D0, colorBrightGreen, IIf( D3, colorPink, IIf( D1, colorRed, colorBlue)));

AlligatorMFI=IIf(D0,1,IIf(D1,2,IIf(D2,3,IIf(D3,4,0))));


_SECTION_END();

_SECTION_BEGIN( "Extra" );
ShowExtra = ParamToggle( "Show Extra", "Yes|No", 0 );

if ( ShowExtra == 0 )
{   Plot( 2, "", IIf( GrnBar, colorBrightGreen, IIf( RedBar, colorRed, colorGrey40)), styleNoTitle | styleOwnScale | styleArea | styleNoLabel );
//    Plot( 2, "", IIf( GrnBar, colorBrightGreen, IIf( AOUB AND ACDB, colorGrey40, IIf( AODB AND ACUB, colorGrey50, IIf( RedBar, colorRed, colorViolet ) ) ) ), styleNoTitle | styleOwnScale | styleArea | styleNoLabel );
    Plot (4, "MFI", dynamic_color, styleOwnScale|styleArea|styleNoLabel|styleNoTitle, -0.5, 100  );
    Plot( Vol, "\nVol (Lot)", colorGrey50, styleHidden );
    Plot( VolAverage, "Vol.Avg(" + WriteVal( Periode, 1.0 ) + ")", colorGreen, styleHidden );
    Plot( MA( C, 200 ), "MA(C,200)", colorGrey40, styleHidden );
    Plot( LLV( L, 60 ), "\nLLV(L,60)", colorGrey40, stylehidden );
}

ShowPlan = ParamToggle( "Show Plan", "Yes|No", 0 );

if ( ShowPlan == 0 )
{
    _N( Title = Title + " - Bars: " + WriteIf( AOUB AND ACUB, EncodeColor( colorGreen ) + "AOUB AND ACUB", WriteIf( AOUB AND ACDB, EncodeColor( colorGrey40 ) + "AOUB AND ACDB", WriteIf( AODB AND ACUB, EncodeColor( colorGrey50 ) + "AODB AND ACUB", WriteIf( AODB AND ACDB, EncodeColor( colorRed ) + "AODB AND ACDB", "-" ) ) ) )
                + "\n" + EncodeColor( colorDefault ) + "BuyPrice = " + WriteVal( BuyPrice, 1.0 ) + ", Risk = " + WriteVal( Risk, 1.2 ) + "%, " + "ExitPoint = " + WriteVal( ExitLong, 1.0 )
      );
}
else
{
    _N( Title = Title + " - Bars: " + WriteIf( AOUB AND ACUB, EncodeColor( colorGreen ) + "AOUB AND ACUB", WriteIf( AOUB AND ACDB, EncodeColor( colorGrey40 ) + "AOUB AND ACDB", WriteIf( AODB AND ACUB, EncodeColor( colorGrey50 ) + "AODB AND ACUB", WriteIf( AODB AND ACDB, EncodeColor( colorRed ) + "AODB AND ACDB", "-" ) ) ) )
      );
}

_SECTION_END();

_SECTION_BEGIN( "Highest High" );
Plot( Ref( Highest( H ), -1 ), "Highest High", ParamColor( "Highest High Color", colorRed ), ParamStyle( "Highest High Style", stylehidden ) );
_SECTION_END();

_SECTION_BEGIN( "Lowest Low" );
Plot( Ref( Lowest( L ), -1 ), "Lowest Low", ParamColor( "Lowest Low Color", colorRed ), ParamStyle( "Lowest Low Style", stylehidden ) );
//Plot( Ref( Lowest( L ), -1 ), "Lowest Low", ParamColor( "Lowest Low Color", ColorRGB ), ParamStyle( "Lowest Low Style", stylehidden ) );
_SECTION_END();

_SECTION_BEGIN("Emiten Name");
//SetChartOptions( 0, chartShowArrows|chartShowDates );
GfxSetOverlayMode(1);
GfxSelectFont("Tahoma", 12, 400 );
GfxSetTextAlign( 0 );// center alignment
GfxSetTextColor( ParamColor( "Warna", colorLightGrey ) );
GfxSetBkMode(0); // transparent
GfxTextOut( Name(),550, 15 );
GfxTextOut( FullName(), 550, 30 );
GfxSelectFont("Tahoma", 10, 400 );
GfxTextOut( SectorId(1)+" - "+IndustryID(1), 550, 45 );
//GfxTextOut( "Sub Sector : "+, 545, 60 );
_SECTION_END();